Transformadas de Laplace con ayuda de software

La transformada de Laplace es una operación que transforma una función, típicamente definida en el dominio del tiempo t, a otra función en el dominio de la variable s, asociada a la frecuencia.  Dicha operación está definida como:

L\lbrace f(t) \rbrace =\int_0^{\infty}{e^{-st}f(t)}dt = F(s)

Es claro que la existencia de dicha transformada estará sujeta a la convergencia de la integral anterior, pero más concretamente se dice que para que exista garantía de existencia de la transformada de una función f(t) esta debe cumplir dos condiciones: no debe tener discontinuidades ireducibles(no infinitas) y deberá crecer no más que una función exponencial.  A este tipo de funciones se les llama “funciones respetables“.  Sin embargo esto no implica que una función no respetable no pueda tener transformada, como por ejemplo la función ln(t) (no respetable), cuya transformada existe.

Para el cálculo de la transformada de Laplace, se usan propiedades que simplifican de manera significativa las operaciones, partiendo de las transformadas de señales elementales, .  Para más detalles, consulte las propiedades en el libro guía del curso.  Sin embargo, aquí vamos a ilustrar con ejemplos como calcularla usando la función laplace(expr,t,s) de Maxima.

Ejemplos – funciones trasladadas, exponenciales y multiplicadas/dividas por t:

Calcular la transformada de Laplace de f(t)=te^{-t}\sin(2t)u(t)

Código:

laplace(%e^(-t)*t*sin(2*t)*unit_step(t), t, s);

Resultado:

(2*(2*s+2))/(s^2+2*s+5)^2

Calcular la transformada de Laplace de f(t)=t\ln(t)u(t)

Código:

laplace(t*log(t)*unit_step(t), t, s);

Resultado:

\frac{-\mathrm{log}\left( s\right) -\gamma+1}{{s}^{2}} 

Calcular la transformada de Laplace de f(t)=u(t)-u(t-a)

Código:

laplace(unit_step(t)-unit_step(t-a), t, s);

Resultado:

1/s-%e^(-a*s)/s

Calcular la transformada de Laplace de f(t)=e^{-(t-a)}u(t-a)

Código:

laplace(%e^(-(t-a))*unit_step(t-a), t, s)$
ratsimp(%);

Resultado:

%e^(-a*s)/(s+1)

Calcular la transformada de Laplace de f(t)=\delta(t)+u(t-a)+(t-a)e^{t-a}u(t-a)

Código:

f(t):=delta(t)+unit_step(t-a)+(t-a)*exp(t-a)*unit_step(t-a)$
laplace(f(t),t,s);

Resultado:

%e^(−a*s)/s+%e^(−a*s)/(s−1)^2+1

Calcular la transformada de Laplace de f(t)=\dfrac{\sinh(t)}{t}u(t)

Código:

assume(s>1);
laplace(sinh(t)/t*unit_step(t), t, s)$
ratsimp(%);
logcontract(%);

Resultado:

(%o1)[s>1]
(%o3) log(s+1)-log(s-1)/2
(%o4) -log(s-1/(s+1))/2

En este caso, podemos decirle a Maxima que asuma que s>1 para que calcule automáticamente la transformada, de otra forma preguntará esto.  También hemos usado la propiedad de contracción de logartimos a fin de simplificar la expresión al máximo.

Calcular la transformada de Laplace de f(t)=\int{t^2\sin(t)}dt

Código:

f(t):=integrate(t^2*sin(t),t)$
laplace(f(t),t,s);

Resultado:

(2*s)/(s^2+1)+(10*s)/(s^2+1)^2−(8*s^3)/(s^2+1)^3

 

Ejemplos de transformación de EDO- funciones derivadas.

Uno de los principales objetivos de introducir la transformada en el curso es justamente tener una herramienta poderosa para resolver ecuaciones diferenciales.  Esto es debido a que la transformada de una función derivada es básicamente la transformada de la función sin derivar pero multiplicada por la variable s (adicionando las condiciones inciales) es decir:

L\lbrace  \dfrac{d^nf(t)}{dt^n}\rbrace  =s^nF(s)-s^{n-1}f(0)-s^{n-2}f'(0)-...-f^{(n-1)}(0)

De esta manera, podemos decir resumidamente que “derivar en el tiempo equivale a multiplicar por s en el dominio de s (frecuencia)”.

De esta forma, dado un PVI, por ejemplo: y''(t)+3y'(t)+2y(t)=u(t) con y'(0)=y(0)=0

Se puede transformar al dominio de s mediante la siguiente secuencia de comandos:

ode:'diff(y(t),t,2)+3*'diff(y(t),t)+2*y(t)=unit_step(t);
atvalue(y(t),t=0,0)$ atvalue('diff(y(t),t),t=0,0)$
laplace(ode,t,s);
solve(%, 'laplace(y(t), t, s));

Cuyo resultado arroja:

(%o1) 'diff(y(t),t,2)+3*('diff(y(t),t,1))+2*y(t)=unit_step(t)
(%o4) s^2*laplace(y(t),t,s)+3*s*laplace(y(t),t,s)+2*laplace(y(t),t,s)=1/s
(%o5) [laplace(y(t),t,s)=1/(s^3+3*s^2+2*s)]

Como puede verse aquí, la transformada de la función y(t) es: Y(s)=\dfrac{1}{s(s^2+3s+2)}.

Observe que hemos usado la función solve() para despejar la transformada (sin calcularla- por eso está precedida por una comilla simple : esto es: laplace()).

Así entonces, si pudieramos saber que función y(t) tiene dicha transformada (transformación inversa) obtendríamos la solución al PVI.